Custom Properties Lookup Table

[Jim Ault]

This is using the FILTER command and a wild card pattern

on mouseUp
  put 51 into tage
  put comma into c
  put "*"& tAge &c& fld "subFld" &c& fld "rsFld" &c& "*" into pattn
  get (the scaledScore["memory"] of field "data1")
  filter it with pattn
  -- put item 4 of it into field "ssFld" (not yet)

  --now check the result
  if the number of lines in it > 1 then
    answer "multiple hits of " & cr & \
        it &  cr & cr  & \
        "using " & pattn
     
  else if the number of lines in it < 1 then
    answer "Nothing matches" &cr & pattn
     
  else
    put item 4 of it into field "ssFld"
  end if
end mouseUp


Jim Ault
Las Vegas

> Charles Szasz wrote:
>> I have set up a custom property set (scaledScore) for a field (data1),
>> with custom properties (memory) and property contents listed below:
>> 
>> 51,1,0,4,2
>> 51,1,1,5,5
>> 51,1,2,6,9
>> 51,1,3,7,16
>> 51,1,4,7,16
>> 51,1,5,7,16
>> 51,1,6,8,25
>> 51,1,7,8,25
>> 51,1,8,8,25
>> 
>> The first row of the 51,1,0,4,2 above represents:
>> age (51), followed by the number of the subtest (1), raw score (0),
>> scaled score (4), percentile (2)
>> 
>> I have been working on a handler to take input from the user for age
>> (tage), subtest field (field "subFld", raw score (field "rsFld").
>> After the user enters the age, subtest number, raw score, the scaled
>> score appears in the field "ssFld" after it is look up in the custom
>> properties.
>> 
>> on mouseUp
>>   put 51 into tage
>>   put tAge,field "subFld",field "rsFld" into theMatch
>>   put the scaledScore["memory"] of field "data1" into theMatch2
>>   if item 1 of theMatch and item 2 of theMatch and item 3 of theMatch
>> = item 1 of theMatch2 and item 2 of theMatch2 and item 3 of theMatch2
>> then
>>     put item 4 of theMatch2 into field "ssFld"
>>   end if
>> end mouseUp
>> 
>> This script does not work and no errors appear in Rev IDE. Can anyone
>> help me with this problem?
>> 
>> 
>> Charles Szasz
>> cszasz at mac.com