Detailed system information

[Richard Gaskin]

Skip Kimpel wrote:

> Has anybody created a script to get detailed information from the user in a
> standalone so that it can be sent back for debugging?
>
> Out of the box I am only finding "systemInformation" and "the platform"
>
> I would love to get many more details such as (on a Windows machine) the
> version of the operating system, browsers installed and versions of those,
> etc.
>
> I was about to start writing code to dig into the registry but I thought I
> would ask here first.
>
> Thank you!

Here's one example of a system profiler I wrote a long time ago, 
hopefully this will give you some ideas for your own:



function fwGestalt
   put "System Profile"&cr into tReport
   put the long date &", "& the time &cr&cr after tReport
   --
   put "Application:" &tab& "MyApp" &cr after tReport
   --
   get the uVersion of cd 1 of stack "MyApp"
   if it is empty then get "N/A"
   put "Version:"  &tab& it &cr after tReport
   --
   get the address
   set the itemDel to ":"
   delete item 1 of it
   put "Location:"&tab& it &cr after tReport
   set the itemdel to comma
   --
   If the platform is "MacOS" then put "Mac OS "&the systemversion into tSys
   else put the systemversion into tSys
   put "System:" &tab& tSys&cr after tReport
   --
   put "CPU Type:" &tab& the machine &cr after tReport
   --
   get item 3 of the screenRect &" X "& item 4 of the screenrect
   put "Screen resolution:"&tab& it &cr after tReport
   --
   put "Window bounding rect:" &tab& the windowboundingrect &cr after 
tReport
   --
   put "Screen depth:"&tab& the screenDepth & "-bit" &cr after tReport
   --
   put "Screen type:"&tab& the screenType &cr after tReport
   --
   put "Screen gamma:"&tab& the screengamma &cr after tReport
   --
   get the qtversion
   if it = "0.0" then get "(Not installed)"
   if the platform is not in "MacOS,Win32" then get "N/A"
   put "QuickTime version:"&tab& it &cr after tReport
   --
   put "Sound volume:" &tab& the playloudness &"%" &cr after tReport
   --
   get the printpapersize
   get (item 1 of it) / 72 &" X "& (item 2 of it) / 72
   put "Printer paper size:"&tab& it &cr after tReport
   --
   put "Print scale:"&tab& the printScale &cr after tReport
   --
   put "Avilable disk space:"&tab& Bytes2Size(the diskspace)&cr after 
tReport
   get the drives
   replace cr with comma&space in it
   put "Drives:" &tab& it &cr after tReport
   --
   return tReport
end fwGestalt




-- 
  Richard Gaskin
  Fourth World Systems
  Software Design and Development for the Desktop, Mobile, and the Web
  ____________________________________________________________________
  Ambassador at FourthWorld.com                http://www.FourthWorld.com